Listing of file='TSIM.BAS;01' on disk='vmedia/snakes_and_ladders-sector.ccvf'
1 REM K
10 REM
*** TIME SIGNATURES IN MUSIC ***
20 REM THIS PROGRAM WILL ASSIST IN
30 REM TEACHING TIME SIGNATURES IN MUSIC
40 REM WRITTEN BY GREG HUBBARD, APRIL 1981
50 REM PHONE (03)241-7094
60 REM (C) COPYRIGHT 1981
100 DIM EI$(4),BL$(2),TS$(6),TI$(4),CO$(4),CO(4)
110 I= 0:K= 0:S= 0:J= 0:A= 0:SC= 0:T= 0:P= 0:D= 0:DL= 0:G= 0:CO= 0
120 CO$= "":NA$= "":J$= "":AN$= "":CA$= "":A$= ""
130 CLEAR 500:PLOT 15,27,24
140 TM= PEEK (32940)+ PEEK (32941)* 256+ 1
150 POKE TM,50:POKE TM+ 2,15:POKE TM+ 4,0
200 REM
SET UP SPECIAL CHARACTERS
210 WH$= " vw tu
"
220 HA$= " vw tua a a a a
"
230 QU$= " vw tu a a a a a
"
240 EI$(1)= " vw tu a a a a p
"
250 EI$(2)= " vw tu a a a a neeeea
a
a
a
a tu
vw"
260 EI$(3)= EI$(2)+ " neeee
vw tu a a a a a
"
270 EI$(4)= EI$(2)+ " neeee
vw tu a a a a neeeea
a
a
a
a tu
vw"
280 XX$= "vw tu
"
290 BL$(1)= " b b b b b b b
b "
300 BL$(2)= BL$(1)+ "m m m m m m m
m "
310 TS$(2)= " en ~a y hd
"
320 TS$(3)= " en ~a gd ez
"
330 TS$(4)= " en ~a en ~a
"
340 TS$(6)= " cd cd cd tf
"
500 REM
TITLE PAGE
510 PLOT 6,3,12
520 PLOT 3,10,4:PRINT " en en pq {e cf en tf pb tu en ab {d {e cf"
530 PLOT 3,10,5:PRINT " a l ab l gd l vd as no a vw a| l gd"
540 PLOT 3,21,9:PRINT "en pb pq ab cf en tf"
550 PLOT 3,21,10:PRINT "l as ab vw gd l vi "
560 GOSUB 52010:PLOT 6,4,12
1000 REM
INTRODUCTION
1010 PLOT 3,12,2:PRINT " en pb en ab en cf a {e cf cf tu pb"
1020 PLOT 3,12,3:PRINT "l as a no l gd l l gd gd vw as"
1030 GOSUB 52030
1040 PLOT 3,12,6:PRINT "|~ tu ab ab en a a a {e tu {d pb"
1050 PLOT 3,12,7:PRINT "b vw vw rs l l l l l no a| as"
1060 GOSUB 52030
1070 PLOT 3,25,10:PRINT "tu {d tu ab en"
1080 PLOT 3,25,11:PRINT "no ld vw vw a "
1090 GOSUB 52020
1100 DATA "WHOLE NOTES","HALF NOTES","QUARTER NOTES"
1110 DATA "EIGHTH NOTES","BAR LINES","TIME SIGNATURES"
1120 RESTORE 1100:FOR K= 0TO 5:PLOT 6,3,3,31,20
1130 IF K= 0THEN PRINT WH$
1140 IF K= 1THEN PRINT HA$
1150 IF K= 2THEN PRINT QU$
1160 IF K= 3THEN PRINT EI$(1)
1170 IF K= 4THEN PLOT 3,26,19:PRINT BL$(1):PLOT 3,36,19:PRINT BL$(2)
1180 IF K= 5THEN PRINT TS$(3)
1190 READ CO$:PLOT 3,32- (LEN (CO$)/ 2),23:PRINT CO$
1200 GOSUB 60050:GOSUB 52020:GOSUB 51000:GOSUB 52020
1210 PLOT 3,0,23,11:NEXT K
1220 PLOT 3,13,20:PRINT TS$(4):GOSUB 52040
1230 PLOT 3,18,20:PRINT QU$:GOSUB 52040
1240 PLOT 3,23,20:PRINT HA$:GOSUB 52040
1250 PLOT 3,28,20:PRINT EI$(2):GOSUB 52040
1260 PLOT 3,38,20:PRINT BL$(1):GOSUB 52040
1270 PLOT 3,43,20:PRINT WH$:GOSUB 52040
1280 PLOT 3,48,20:PRINT BL$(2):GOSUB 52040
1290 PLOT 3,7,23:PRINT "AND HOW TO PUT THEM ALL TOGETHER TO MAKE RHYTHMS"
1300 GOSUB 60050:GOSUB 52010:GOSUB 50000
1500 REM
HELLO
1510 PLOT 3,22,2,14:PRINT "I AM COMPUCOLOR 11"
1520 PLOT 3,5,5:PRINT "I DIDN'T CATCH YOUR NAME, THOUGH. I WOULD LIKE TO KNOW,"
1530 PRINT "SINCE WE WILL BE WORKING TOGETHER. TYPE IN YOUR NAME AND, WHEN"
1540 PRINT "YOU HAVE, HIT THE BLACK KEY MARKED RETURN/ENTER. IF YOU MAKE A"
1550 PRINT "MISTAKE, HIT THE GREY ARROW LEFT KEY UNTIL IT HAS BEEN ERASED."
1560 GOSUB 60050:PLOT 3,0,9:INPUT "YOUR NAME IS? ";NA$:PRINT
1570 IF NA$= ""THEN PRINT "COME ON, YOU MUST HAVE A NAME!"
1580 IF NA$= ""THEN GOSUB 52020:PLOT 28,11:GOTO 1560
1590 PRINT "GLAD TO MEET YOU, ";NA$:PRINT
1600 PRINT "BEFORE WE CAN BEGIN TO LEARN ABOUT TIME-SIGNATURES,"
1610 PRINT "WE MUST FIRST LOOK AT VALUES OF NOTES."
1620 PRINT "IF YOU ALREADY KNOW YOUR NOTE VALUES, ";NA$
1630 PRINT "TYPE 'JUMP' AND HIT RETURN."
1640 INPUT "TO SEE A DISPLAY OF NOTE VALUES, JUST HIT RETURN. ";J$
1650 IF LEFT$ (J$,1)< > "J"THEN GOTO 53000
2000 REM
NOTE-VALUE TEST
2010 PLOT 12,14,3,0,2:PRINT "HERE IS A QUICK TEST OF YOUR NOTE VALUES"
2020 PRINT
2030 PRINT "W=WHOLE NOTE","H=HALF NOTE","Q=QUARTER NOTE","E=EIGHTH NOTE"
2040 PRINT "________________________________________________________________"
2050 DATA "Q","A QUARTER NOTE","W","A WHOLE NOTE"
2060 DATA "H","A HALF NOTE","E","AN EIGHTH NOTE"
2070 RESTORE 2050:SC= 0:FOR K= 0TO 3:READ C$,CO$
2080 PLOT 3,23,10,14:PRINT "WHAT IS THIS NOTE?":PLOT 15,6,6,3,31,20
2090 IF K= 0THEN PRINT QU$
2100 IF K= 1THEN PRINT WH$
2110 IF K= 2THEN PRINT HA$
2120 IF K= 3THEN PRINT EI$(1)
2130 GOSUB 60050:PLOT 14,3,15,26:INPUT "TYPE YOUR ANSWER AND HIT RETURN: ";AN$
2140 IF LEFT$ (AN$,1)= C$THEN SC= SC+ 1:PLOT 3,19,29:PRINT "YES - IT IS "CO$" !!!":GOTO 2160
2150 PLOT 3,13,29:PRINT "NO, THAT'S WRONG - IT'S "CO$" !!!"
2160 GOSUB 52020:GOSUB 51000
2170 FOR I= 0TO 22:PLOT 3,0,31- I,11:NEXT I:NEXT K
2180 IF SC= 3THEN 2230
2190 IF SC< 3THEN 2240
2200 PLOT 3,14,14:PRINT "CONGRATULATIONS - A PERFECT SCORE !!!"
2210 PLOT 3,20,18:PRINT "LET'S CONTINUE, ";NA$
2220 GOSUB 52000:GOSUB 50000:GOTO 2500
2230 PLOT 3,16,14:PRINT "YOU GOT 1 QUESTION WRONG, ";NA$:GOTO 2250
2240 PLOT 3,16,14:PRINT "YOU GOT"4- SC" QUESTIONS WRONG, "NA$
2250 PLOT 3,10,17:PRINT "LET'S LOOK AT THE VALUE OF NOTES TABLE AGAIN"
2260 GOSUB 52000:GOTO 53000
2500 REM
BAR LINES
2510 PRINT :PRINT "AS YOU PROBABLY KNOW, "NA$", ALL MUSIC HAS A BEAT OR RHYTHM."
2520 PRINT "THESE BEATS ARE GROUPED TOGETHER INTO BARS."
2530 PRINT :PRINT "WHEN WE ARE WRITING MUSIC, WE USE BAR LINES TO SHOW"
2540 PRINT "WHERE ONE BAR ENDS AND THE NEXT BAR BEGINS."
2550 PRINT "A PIECE OF MUSIC ALWAYS ENDS WITH A DOUBLE BAR LINE."
2560 PRINT :INPUT "HIT RETURN TO CONTINUE ";A:PLOT 6,3
2570 PLOT 3,1,18:PRINT TS$(4):PLOT 3,4,18:PRINT QU$:PLOT 3,7,18:PRINT QU$
2580 PLOT 3,10,18:PRINT HA$:PLOT 3,13,18:PRINT BL$(1):PLOT 3,15,18:PRINT QU$
2590 PLOT 3,18,18:PRINT QU$:PLOT 3,21,18:PRINT EI$(4):PLOT 3,39,18:PRINT BL$(1)
2600 PLOT 3,41,18:PRINT HA$:PLOT 3,44,18:PRINT QU$:PLOT 3,47,18:PRINT QU$
2610 PLOT 3,50,18:PRINT BL$(1):PLOT 3,53,18:PRINT WH$:PLOT 3,56,18:PRINT BL$(2)
2620 PLOT 3,14,21:PRINT "THIS PIECE OF MUSIC HAS FOUR BARS."
2630 GOSUB 52000:PRINT :PRINT :PRINT
2640 PRINT "NOW THAT WE KNOW OUR NOTE VALUES AND ABOUT THE USE"
2650 PRINT "OF BAR LINES, "NA$", WE CAN GO ON TO LOOK AT TIME SIGNATURES."
2660 PRINT :INPUT "HIT RETURN TO CONTINUE ";A
2670 GOSUB 50000
3000 REM
TIME SIGNATURES
3010 PRINT :PRINT " A TIME SIGNATURE IS PLACED AT THE VERY START OF A"
3020 PRINT "PIECE OF MUSIC TO SET THE BEAT. THERE MAY ALSO BE"
3030 PRINT "OTHER TIME SIGNATURES PLACED WITHIN THE PIECE TO"
3040 PRINT "CHANGE THE BEAT."
3050 PRINT :PRINT " A TIME SIGNATURE IS SIMPLY ONE NUMBER ABOVE ANOTHER"
3060 PRINT "NUMBER. THE TOP NUMBER TELLS US THE NUMBER OF BEATS IN"
3070 PRINT "A BAR AND THE BOTTOM NUMBER TELLS US WHAT TYPE OF BEATS"
3080 PRINT "THEY ARE."
3090 PRINT :PRINT "OK, "NA$". LET'S HAVE A LOOK AT A FEW TIME SIGNATURES."
3100 PRINT :INPUT "HIT RETURN TO CONTINUE";A
3110 DATA "TWO-FOUR TIME HAS TWO QUARTER-NOTE (CROTCHET) BEATS PER BAR"
3120 DATA ""
3130 DATA "THREE-FOUR TIME HAS THREE QUARTER-NOTE (CROTCHET) BEATS PER BAR"
3140 DATA ""
3150 DATA "FOUR-FOUR TIME HAS FOUR QUARTER-NOTE (CROTCHET) BEATS PER BAR"
3160 DATA "THE THIRD BEAT IS ALSO STRESSED BUT THE FIRST IS STRONGER"
3170 DATA "SIX-EIGHT TIME HAS SIX EIGHTH-NOTE (QUAVER) BEATS PER BAR"
3180 DATA "THE FOURTH BEAT IS ALSO STRESSED BUT THE FIRST IS STRONGER"
3190 RESTORE 3110:FOR J= 2TO 6:IF J= 5THEN J= 6
3200 READ CO$,CA$:PLOT 3,5,21,6,4:PRINT TS$(J)
3210 PLOT 3,9,18,6,3:PRINT "NUMBER OF BEATS IN A BAR"
3220 PLOT 3,9,21,6,1:PRINT "TYPE OF BEATS THEY ARE"
3230 PLOT 3,0,25,6,5,14:PRINT CO$
3240 PLOT 15,6,6:PRINT "THE FIRST BEAT OF EACH BAR IS STRESSED"
3250 PRINT CA$
3260 PRINT :INPUT "HIT RETURN TO CONTINUE";A
3270 REM
3280 FOR I= 31TO 13STEP - 1:PLOT 15,6,35,3,0,I,11,6,6,3,0,I+ 1,11:NEXT I:PLOT 3,0,13,11
3290 NEXT J
3300 PRINT :PRINT " NOW THAT WE HAVE THE GENERAL IDEA, "NA$","
3310 PRINT "LET'S HAVE A LISTEN TO A FEW TIME SIGNATURES."
3320 PRINT :PRINT "MAKE SURE THAT YOU HAVE YOUR 'SOUND-WARE'"
3330 PRINT "CONNECTED AND SWITCHED ON!"
3340 PRINT :INPUT "HIT RETURN TO CONTINUE";A
3350 GOSUB 50000
4000 REM
TIME SIGNATURE DEMONSTRATION
4010 DATA "TWO-FOUR TIME"
4020 DATA "TWO QUARTER-NOTE BEATS PER BAR"
4030 DATA "THREE-FOUR TIME"
4040 DATA "THREE QUARTER-NOTE BEATS PER BAR"
4050 DATA "FOUR-FOUR TIME"
4060 DATA "FOUR QUARTER-NOTE BEATS PER BAR"
4070 DATA "SIX-EIGHT TIME"
4080 DATA "SIX EIGHTH-NOTE BEATS PER BAR"
4090 RESTORE 4010:FOR I= 1TO 4:READ TI$(I),CO$(I):NEXT I
4100 FOR T= 1TO 4
4110 PLOT 3,32- LEN (TI$(T))/ 2,3,6,3,14:PRINT TI$(T)
4120 PLOT 3,32- LEN (CO$(T))/ 2,18,6,5:PRINT CO$(T)
4130 PLOT 15,6,6:ON TGOSUB 10000,11000,12000,13000
4140 PLOT 3,10,22:PRINT "TO HEAR THIS BEAT, HIT RETURN"
4150 PLOT 3,10,24:INPUT "TO CONTINUE, TYPE 'JUMP' AND HIT RETURN ";A$
4160 IF LEFT$ (A$,1)= "J"THEN 4180
4170 ON TGOSUB 10500,11500,12500,13500:GOTO 4140
4180 GOSUB 50000:NEXT T
4190 IF FL= 1THEN GOTO 6000
5000 REM
TIME SIGNATURE TEST
5010 PLOT 12,14,3,15,2:PRINT "HERE IS A TEST ON TIME SIGNATURES"
5020 PRINT :PRINT "2=TWO-FOUR","3=THREE-FOUR","4=FOUR-FOUR","6=SIX-EIGHT"
5030 PRINT "________________________________________________________________"
5040 DATA "FOUR-FOUR",4,"THREE-FOUR",3,"SIX-EIGHT",6,"TWO-FOUR",2
5050 RESTORE 5040:SC= 0:FOR L= 1TO 4:READ CO$(L),CO(L):NEXT L
5060 FOR L= 1TO 4:ON LGOSUB 12020,11020,13020,10020
5070 PLOT 3,14,18:PRINT "WHAT SHOULD THE TIME SIGNATURE BE? "
5080 GOSUB 60050:PLOT 3,14,21,14:INPUT "TYPE YOUR ANSWER AND HIT RETURN: ";AN$
5090 IF VAL (LEFT$ (AN$,1))= CO(L)THEN SC= SC+ 1:PLOT 3,19,27:PRINT "YES - IT IS "CO$(L)" !!!":GOTO 5110
5100 PLOT 3,13,27:PRINT "NO, THAT'S WRONG - IT IS "CO$(L)" !!!"
5110 GOSUB 52020:PLOT 15
5120 IF L= 1THEN GOSUB 12000:GOSUB 12500
5130 IF L= 2THEN GOSUB 11000:GOSUB 11500
5140 IF L= 3THEN GOSUB 13000:GOSUB 13500
5150 IF L= 4THEN GOSUB 10000:GOSUB 10500
5160 GOSUB 52020:FOR I= 0TO 22:PLOT 15,3,0,31- I,11:NEXT I:NEXT L:PLOT 14
5170 IF SC= 3THEN 5220
5180 IF SC< 3THEN 5230
5190 PLOT 3,14,14:PRINT "CONGRATULATIONS - A PERFECT SCORE !!!"
5200 PLOT 3,20,18:PRINT "LET'S CONTINUE, ";NA$
5210 GOTO 5240
5220 PLOT 3,16,14:PRINT "YOU GOT 1 QUESTION WRONG, ";NA$:GOTO 5240
5230 PLOT 3,16,14:PRINT "YOU GOT"4- SC" QUESTIONS WRONG, "NA$
5240 GOSUB 52000:GOSUB 50000
6000 REM
GOOD-BYE
6010 PRINT :PRINT "WELL THAT'S ALL, "NA$"."
6020 PRINT "I HOPE YOU ENJOYED IT AS MUCH AS I DID!"
6030 PRINT :PRINT "IF YOU'D LIKE TO REVIEW THE TIME SIGNATURE DEMONSTRATION,"
6040 PRINT "TYPE 'DEMO' AND HIT RETURN."
6050 PRINT :PRINT "IF YOU'D LIKE TO TRY THE TEST AGAIN,"
6060 PRINT "TYPE 'TEST' AND HIT RETURN."
6070 PRINT :INPUT "HIT RETURN TO FINISH ";A$
6080 IF LEFT$ (A$,1)= "D"THEN FL= 1:GOSUB 50000:GOTO 4000
6090 IF LEFT$ (A$,1)= "T"THEN GOSUB 50000:GOTO 5000
6100 FOR I= 0TO 100
6110 X= INT (RND (1)* 64):Y= INT (RND (1)* 32):C= INT (RND (1)* 8)
6120 P= INT (RND (1)* 100)+ 5:D= 25
6130 PLOT 3,X,Y,6,C:PRINT EI$(4):GOSUB 60000:NEXT I
9999 PLOT 1
10000 REM
2/4 TIME DEMO
10010 PLOT 3,11,15:PRINT TS$(2)
10020 PLOT 3,15,15:PRINT QU$:PLOT 3,19,15:PRINT QU$
10030 PLOT 3,22,15:PRINT BL$(1):PLOT 3,25,15:PRINT QU$:PLOT 3,29,15:PRINT QU$
10040 PLOT 3,32,15:PRINT BL$(1):PLOT 3,35,15:PRINT QU$:PLOT 3,39,15:PRINT QU$
10050 PLOT 3,42,15:PRINT BL$(1):PLOT 3,45,15:PRINT QU$:PLOT 3,49,15:PRINT QU$
10060 PLOT 3,52,15:PRINT BL$(2):RETURN
10070 DATA 15,55,200,19,110,100,25,55,200,29,110,100
10080 DATA 35,55,200,39,110,100,45,55,200,49,110,100
10500 RESTORE 10070:FOR K= 0TO 7:READ C,P,D
10510 PLOT 3,C,15,6,1:PRINT QU$:GOSUB 60000:FOR I= 0TO 20:NEXT I
10520 PLOT 3,C,15,6,6:PRINT QU$:NEXT K:RETURN
11000 REM
3/4 TIME DEMO
11010 PLOT 3,4,15:PRINT TS$(3)
11020 PLOT 3,8,15:PRINT QU$:PLOT 3,12,15:PRINT QU$
11030 PLOT 3,16,15:PRINT QU$:PLOT 3,19,15:PRINT BL$(1):PLOT 3,22,15:PRINT QU$
11040 PLOT 3,26,15:PRINT QU$:PLOT 3,30,15:PRINT QU$:PLOT 3,33,15:PRINT BL$(1)
11050 PLOT 3,36,15:PRINT QU$:PLOT 3,40,15:PRINT QU$:PLOT 3,44,15:PRINT QU$
11060 PLOT 3,47,15:PRINT BL$(1):PLOT 3,50,15:PRINT QU$:PLOT 3,54,15:PRINT QU$
11070 PLOT 3,58,15:PRINT QU$:PLOT 3,61,15:PRINT BL$(2):RETURN
11080 DATA 8,55,200,12,110,100,16,110,100,22,55,200,26,110,100,30,110,100
11090 DATA 36,55,200,40,110,100,44,110,100,50,55,200,54,110,100,58,110,100
11500 RESTORE 11080:FOR K= 0TO 11:READ C,P,D
11510 PLOT 3,C,15,6,1:PRINT QU$:GOSUB 60000:FOR I= 0TO 20:NEXT I
11520 PLOT 3,C,15,6,6:PRINT QU$:NEXT K:RETURN
12000 REM
4/4 TIME DEMO
12010 PLOT 3,12,15:PRINT TS$(4)
12020 PLOT 3,16,15:PRINT QU$:PLOT 3,20,15:PRINT QU$
12030 PLOT 3,24,15:PRINT QU$:PLOT 3,28,15:PRINT QU$:PLOT 3,31,15:PRINT BL$(1)
12040 PLOT 3,34,15:PRINT QU$:PLOT 3,38,15:PRINT QU$:PLOT 3,42,15:PRINT QU$
12050 PLOT 3,46,15:PRINT QU$:PLOT 3,49,15:PRINT BL$(2):RETURN
12060 DATA 16,55,200,10,20,110,50,20,24,110,100,10,28,110,50,20
12070 DATA 34,55,200,10,38,110,50,20,42,110,100,10,46,110,50,20
12500 FOR J= 0TO 1:RESTORE 12060:FOR K= 0TO 7:READ C,P,D,DL
12510 PLOT 3,C,15,6,1:PRINT QU$:GOSUB 60000:FOR I= 0TO 20:NEXT I
12520 FOR G= 0TO DL:NEXT G:PLOT 3,C,15,6,6:PRINT QU$
12530 NEXT K:NEXT J:RETURN
13000 REM
6/8 TIME DEMO
13010 PLOT 3,1,15:PRINT TS$(6)
13020 PLOT 3,5,15:PRINT EI$(3)
13030 PLOT 3,19,15:PRINT EI$(3):PLOT 3,32,15:PRINT BL$(1)
13040 PLOT 3,35,15:PRINT EI$(3):PLOT 3,49,15:PRINT EI$(3)
13050 PLOT 3,62,15:PRINT BL$(2):RETURN
13060 DATA 5,55,200,10,10,110,50,20,15,110,50,20
13070 DATA 19,110,100,10,24,110,50,20,29,110,50,20
13080 DATA 35,55,200,10,40,110,50,20,45,110,50,20
13090 DATA 49,110,100,10,54,110,50,20,59,110,50,20
13500 FOR J= 0TO 1:RESTORE 13060:FOR K= 0TO 11:READ C,P,D,DL
13510 PLOT 3,C,15,6,1:PRINT XX$:GOSUB 60000
13520 FOR G= 0TO DL:NEXT G:PLOT 3,C,15,6,6:PRINT XX$
13530 NEXT K:NEXT J:RETURN
49999 END
50000 REM
ERASE PAGE
50010 FOR I= 31TO 0STEP - 1:PLOT 15,6,35,3,0,I,11,6,6,3,0,I+ 1,11:NEXT I:PLOT 28,11:RETURN
50020 PLOT 2,0,63,242,127,63,240:FOR I= 1TO 63:PLOT 18:NEXT I
50030 FOR I= 1TO 127:PLOT 132:NEXT I:FOR I= 1TO 63:PLOT 33:NEXT I
50040 PLOT 255:RETURN
51000 REM
DO SCROLL
51010 X= 26:Y= 12:H= 10:W= 12:C= 1:GOSUB 60100
51020 FOR I= 1TO 12
51030 S= CALL (1)
51040 FOR J= 0TO 30:NEXT J
51050 NEXT I
51060 RETURN
52000 REM
WAIT A WHILE
52010 FOR I= 0TO 3000:NEXT :RETURN
52020 FOR I= 0TO 1000:NEXT :RETURN
52030 FOR I= 0TO 500:NEXT :RETURN
52040 FOR I= 0TO 200:NEXT :RETURN
53000 REM
NOTE VALUE TABLE
53010 PLOT 12,3,26,1,14:PRINT "VALUES OF NOTES"
53020 PRINT "________________________________________________________________"
53030 PRINT " 1 WHOLE-NOTE"TAB( 52)"1 SEMIBREVE"
53040 PRINT " EQUALS"TAB( 34)WH$TAB( 56)"EQUALS"
53050 PRINT :PRINT :PRINT
53060 PRINT " 2 HALF-NOTES"TAB( 52)"2 MINIMS"
53070 PRINT " OR"TAB( 54)"OR"
53080 PRINT :PRINT TAB( 24)HA$TAB( 50)HA$
53090 PRINT :PRINT :PRINT
53100 PRINT " 4 QUARTER-NOTES"TAB( 52)"4 CROTCHETS"
53110 PRINT " OR"TAB( 54)"OR"
53120 PLOT 3,19,19:PRINT QU$:PLOT 3,28,19:PRINT QU$
53130 PLOT 3,38,19:PRINT QU$:PLOT 3,47,19:PRINT QU$
53140 PRINT :PRINT :PRINT :PRINT
53150 PRINT " 8 EIGHTH-NOTES"TAB( 52)"8 QUAVERS"
53160 PLOT 3,16,26:PRINT EI$(1):PLOT 3,21,26:PRINT EI$(1)
53170 PLOT 3,25,26:PRINT EI$(2):PLOT 3,34,26:PRINT EI$(4)
53180 PLOT 3,8,29:PRINT "STUDY THIS TABLE AND, WHEN YOU THINK YOU ARE READY,"
53190 :PLOT 3,8,30:INPUT "HIT RETURN FOR A QUICK TEST!";A
53200 GOTO 2000
60000 REM
SOUND POKER
60010 AD= TM:DA= P:GOSUB 60500
60020 AD= TM+ 2:DA= D:GOSUB 60500
60030 S= CALL (0):RETURN
60050 P= 10:D= 1000:GOTO 60000
60100 REM
SCROLL POKER
60110 DA= 28672+ 128* Y+ X+ X:AD= TM+ 126:GOSUB 60500
60120 DA= 128- W- W:AD= TM+ 149:GOSUB 60500
60130 POKE TM+ 129,H- 1:POKE TM+ 131,W* (C+ 1)
60140 POKE TM+ 143,35* (1- C):RETURN
60500 REM
MULTI POKER
60510 Z1= INT (DA/ 256):Z2= DA- Z1* 256
60520 POKE AD,Z2:N= N+ 1:POKE AD+ 1,Z1:RETURN