Compucolor.org – Virtual Media

Listing of file='TRIP.BAS;01' on disk='vmedia/nsw_ug_1-sideB-sector.ccvf'

10 POKE 33289,80
20 REM  TRIP ANAYLYSIS - BASIC
30 REM  ******************** DATA INITIATION ****************
40 DIM D$(15)
50 DIM M(15)
60 DIM F(15)
70 DIM L(15)
80 DIM O(15)
90 DIM T(15)
100 PRINT "ENTER THE NAME FOR THE TRIP"
110 INPUT N$
120 PRINT "ENTER THE MILE/GALLON YOU EXPECT TO ACHIEVE "
130 INPUT C
140 PRINT "ENTER THE AVERAGE COST PER GALLON YOU EXPECT TO PAY"
150 INPUT G
160 PRINT "ENTER THE NUMBER OF DAYS IT WILL TAKE YOU "
170 INPUT D1
180 FOR J= 1TO D1
190 PRINT "FOR DAY";J
200 PRINT "ENTER STOPPING POINT,MILES TRAVELED"
210 INPUT D$(J),M(J)
220 PRINT "ENTER COST OF MEALS,LODG,OTHR,I.E.,75,25,50,10"
230 INPUT F(J),L(J),O(J)
240 NEXT J
250 REM  ************** PRINT OF RESULTS *********************
260 PRINT
270 PRINT
280 PRINT "**************************************************"
290 PRINT "              RESULTS OF ANALYSIS "
300 PRINT "**************************************************"
310 PRINT
320 PRINT "TRIP NAME;  ";N$
330 PRINT
340 PRINT "DAY";TAB( 10);"STOP AT";TAB( 20);"MILES";TAB( 28);"GAS$";
350 PRINT TAB( 36);"FOOD$";TAB( 44);"LODGE$";TAB( 52);"OTHER$";
360 PRINT TAB( 60);"TOTAL$"
370 PRINT "------";TAB( 10);"-------";TAB( 20);"------";
380 PRINT TAB( 28);"------";
390 PRINT TAB( 36);"-----";TAB( 44);"------";TAB( 52)"------";
400 PRINT TAB( 60);"-----"
410 FOR J= 1TO D1
420 X= M(J)/ C* G
430 PRINT "DAY";J;TAB( 10);D$(J);TAB( 20);M(J);TAB( 28);X;
440 PRINT TAB( 36);F(J);TAB( 44);L(J);TAB( 52);O(J);TAB( 60);
450 T(J)= X+ F(J)+ L(J)+ O(J)
460 X1= X1+ X
470 M1= M1+ M(J)
480 F1= F1+ F(J)
490 L1= L1+ L(J)
500 O1= O1+ O(J)
510 PRINT TAB( 60);T(J)
520 T1= T1+ T(J)
530 T(J)= O
540 PRINT
550 NEXT J
560 PRINT TAB( 20);"--------";TAB( 28);"--------";TAB( 36);
570 PRINT "-----";TAB( 44);"-----";TAB( 52);"-----";TAB( 60);
580 PRINT "-----"
590 PRINT TAB( 10);"TOTAL";TAB( 20);M1;TAB( 28);X1;TAB( 36);F1;TAB( 044);
600 PRINT L1;TAB( 52);O1;TAB( 60);T1
610 PRINT
620 REM  ******************* PROGRAM TERMINATION POINT *******
630 PRINT
640 PRINT
650 END