Compucolor.org – Virtual Media

Listing of file='STREET.BAS;01' on disk='vmedia/chip_90-sector.ccvf'

10 GOTO 70
20 CV= CV+ 1:RETURN
30 CV= CV- 1:RETURN
40 PLOT 3,0,29:INPUT "ARE YOU SURE (Y/N)? ";Z$:RETURN
50 PLOT 3,0,29,11:RETURN
60 GOSUB 50:PLOT 3,0,29:INPUT "PRESS 'RETURN' ";Z:RETURN
70 CLEAR 1000:FOR K= 1TO PEEK (33209):X= RND (1):NEXT K
80 DIM T$(6),T(6,11),TB(9,10),A(8,2),B(2,10),S(5,11),U(10),M(10)
90 C$= "               ":D$= "                    "
100 A1$= "STREET CONDITIONS HAVE":A2$= "TRAFFIC SAFETY HAS"
110 A3$= "ON-SCHEDULE PERFORMANCE HAS":A4$= "THERE IS DISSATISFACTION WITH"
120 A5$= "TWO STRAIGHT YEARS":A6$= "THIS YEAR":A7$= "BUS DOWNTIME HAS"
130 A8$= "THE CITY COMMISSION"
140 PLOT 6,4
150 PLOT 12:FOR X= 10TO 115:PLOT 2,X,52,X,92,255:NEXT X
160 FOR Y= 52TO 92:PLOT 2,10,Y,115,Y,255:NEXT Y
170 PLOT 6,3,3,22,10:PRINT "STREETS OF THE CITY"
180 PLOT 3,30,13:PRINT "BY"
190 PLOT 3,23,16:PRINT "KENNETH R. MURRAY"
200 PLOT 3,15,23:PRINT "ADAPTED FROM 'CREATIVE COMPUTING'"
210 PLOT 3,18,25:PRINT "APRIL 1981, BY RICK TAUBOLD"
220 PLOT 6,2
230 DEF FN XR(RN)= INT (RND (1)* RN)+ 1
240 S$(1)= "RIDERSHIP":S$(2)= "FLEET AGE":S$(3)= "DOWNTIME"
250 S$(4)= "SERVICE DELAY":S$(5)= "FLEET SIZE"
260 T$(2)= "PRIMARY STREET MILEAGE":T$(3)= "INTERSTATE MILEAGE"
270 T$(4)= "STREET CONDITION INDEX":T$(5)= "TRAFFIC SAFETY INDEX"
280 T$(1)= "LOCAL STREET MILEAGE":T$(6)= "VEHICLE MILES"
290 RESTORE :FOR R= 1TO 8:FOR C= 1TO 2:READ A(R,C):NEXT C,R
300 DATA  128,191,384,431,640,687,704,767,896,959,15,975,31,991,47,1007
310 YR= 0:CV= 11:G1= 0:G3= 0:B= 50:P1= 12E04:P2= 75000:M9= FN XR(150)* 1000
320 CI= (((FN XR(250)+ 250)* 1000)+ 1E06)/ 2
330 MI= FN XR(5000)+ 35000
340 T(1,YR)= 450+ FN XR(100):T(2,YR)= 85+ FN XR(25):T(3,YR)= 0
350 T(4,YR)= FN XR(50)* .1+ 6:T(5,YR)= FN XR(50)* .1+ 6
360 XX= 3000+ FN XR(3000):XY= 7000+ FN XR(3000):XZ= 2E04+ FN XR(8000)
370 T(6,YR)= (XX* T(1,YR))+ (XY* T(2,YR))
380 TB(1,YR)= (T(6,YR)/ 1.6)+ 3E05:PT= TB(1,YR)* (((30+ FN XR(20))* 0.01))
390 TB(8,YR)= TB(1,YR):TB(2,YR)= 1
400 TB(3,YR)= (FN XR(500)* 1000)+ 21E05:TB(9,YR)= TB(3,YR)
410 MN= (T(1,YR)* MI* .16* (T(4,YR)* .1))+ (T(2,YR)* MI* .5* (T(4,YR)* .1))+ (T(3,YR)* MI)
420 SN= MN* .04* T(5,YR):TB(6,YR)= MN:TB(7,YR)= SN
430 S(1,YR)= FN XR(350)* 1000+ 55E04:S(5,YR)= INT (FN XR(10)+ 15):MI= INT (FN XR(3000)+ 5000)
440 BF= 0:M3= 200:FOR X= 1TO S(5,YR)
450 BF= BF+ FN XR(12)+ 3
460 NEXT X
470 S(2,YR)= INT ((BF/ S(5,YR))* 10)* .1:M2= (M1* S(5,YR))+ (M3* BF)
480 S= (FN XR(300)+ 500)* .01:S1= 6:S2= 12:S3= 6:M5= (S1* S2* S3* 312* S)+ M9
490 S4= .35:B(1,YR)= (FN XR(500)* 1000)+ 2E05
500 S(3,YR)= INT (S(2,YR)/ 3)+ 6+ (FN XR(50)* .1)
510 S(4,YR)= INT (S(3,YR)/ 3)+ 6+ (FN XR(50)* .1)
520 S(1,YR)= S(1,YR)- (((S(3,YR)+ S(4,YR))* .01)* S(1,YR))
530 BE= M5:M2= M2+ (M5* .1):BD= M2
540 T(4,11)= INT (T(4,YR)* .4):T(5,11)= INT (T(5,YR)* .4)
550 S(1,11)= S(1,YR)* 4:S(2,11)= INT (S(2,YR)* .4)
560 S(3,11)= INT (S(3,YR)* .4):S(4,11)= INT (S(4,YR)* .4)
570 T(2,11)= 44+ T(2,YR):T(3,11)= 16
580 PLOT 12,6,6:PRINT :PRINT "YOUR GOALS FOR THE PLAN ARE:":PRINT
590 PRINT "STANDARD";TAB( 30)"PRESENT";TAB( 45)"GOAL":PRINT
600 FOR X= 2TO 5:PRINT T$(X);TAB( 30)T(X,YR);TAB( 45)T(X,11):NEXT X:PRINT
610 FOR X= 1TO 4:IF X= 1GOTO 630
620 PRINT S$(X);TAB( 30)S(X,YR);TAB( 45)S(X,11):NEXT X:GOTO 640
630 PRINT S$(X);TAB( 30)S(X,YR);TAB( 45)S(X,11):NEXT X
640 PLOT 3,25,18:PRINT "GOOD LUCK!":GOSUB 60
650 YR= YR+ 1:A= YR- 1:D= YR- 2:FOR X= 1TO 5:S(X,YR)= S(X,A):NEXT X
660 FOR X= 1TO 6:T(X,YR)= T(X,A):NEXT X
670 FOR X= 1TO 9:TB(X,YR)= TB(X,A):NEXT X
680 B(1,YR)= B(1,A):B(2,YR)= B(2,A)
690 GG= 0:IF FN XR(10)< 5THEN GG= (FN XR(6)* P1)
700 B(2,YR)= B(2,YR)+ GG:IF B(2,YR)> P1* 10THEN B(2,YR)= P1* 10
710 IF YR= 1GOTO 730
720 I= (FN XR(10)+ 5)* .01:P1= P1+ (P1* I):P2= P2+ (P2* I):M9= M9+ (M9* I)
730 B(1,YR)= B(1,A):B(2,YR)= B(2,A)
740 GG= 0:IF FN XR(10)< 5THEN GG= FN XR(6)* P1
750 B(2,YR)= B(2,YR)+ GG:IF YR= 1GOTO 910
760 MI= MI+ (MI* I):CI= CI+ (CI* I):TB(1,YR)= TB(1,YR)+ TB(1,YR)* I
770 IF YR> 2AND T(4,YR)> T(4,D)THEN CI= CI* 1.1
780 M1= M1+ (M1* I):M3= M3+ (M3* I):M2= M1* S(5,YR)+ M3* BF
790 IF I> .11THEN T(1,YR)= T(1,YR)+ FN XR(7)
800 IF I< .11AND I> .08THEN T(1,YR)= T(1,YR)+ FN XR(15)
810 IF I< .08THEN T(1,YR)= T(1,YR)+ FN XR(22)
820 AA= (XX* (T(1,YR)- T(1,A)))+ (XY* (T(2,YR)- T(2,D)))+ (XZ* (T(3,YR)- T(3,D)))
830 T(6,YR)= T(6,YR)+ AA
840 TB(1,YR)= ((T(6,YR))/ 1.6)+ (TB(1,YR)* I)
850 PT= PT+ (PT* (I+ .02))+ (PT* (((S(5,YR)- S(5,A))/ S(5,A))/ 2))
860 TB(3,YR)= TB(3,YR)+ TB(3,YR)* (I- .02):S(1,YR)= S(1,YR)+ (S(1,YR)* .02)
870 TB(9,YR)= TB(9,YR)+ TB(3,YR)+ B1:TB(8,YR)= TB(8,YR)+ TB(1,YR)
880 MN= (T(1,YR)* MI* .16* (T(4,YR)* .1))+ (T(2,YR)* MI* .5* (T(4,YR)* .1))+ T(3,YR)* MI
890 MN= MN* .6+ ((MN* 4)* (1+ U* .01))
900 SN= MN* .04* T(5,YR):SN= SN* .6+ ((SN* .4)* (1+ U* .01))
910 PLOT 12:PRINT :PRINT "YOUR TRANSIT AUTHORITY OPTIONS ARE:":PRINT
920 PRINT TAB( 5)"1. ROUTES":PRINT TAB( 5)"2. HOURS OF OPERATION"
930 PRINT TAB( 5)"3. DAYS OF SERVICE":PRINT TAB( 5)"4. FARE":PRINT TAB( 5)"5. TO CONTINUE"
940 PRINT :INPUT "YOUR CHOICE: ";Z:Z= INT (Z):IF Z< 1OR Z> 5GOTO 910
950 PLOT 6,6:ON ZGOTO 960,1020,1120,1200,1320
960 PLOT 3,0,20:PRINT "PRESENT # OF ROUTES=";S1
970 PLOT 3,0,22,6,4:INPUT "NEW # OF ROUTES (MIN.=6, MAX.=25) ";S1(1)
980 GOSUB 50:S1(1)= INT (S1(1))
990 IF S1(1)< 6GOTO 1270
1000 IF S1(1)> 25GOTO 1270
1010 GOTO 910
1020 PLOT 3,0,20:PRINT "POSSIBLE HOURS OF OPERATION ARE:":IF S2= 12THEN S2= 1
1030 IF S2= 17THEN S2= 2
1040 IF S2= 24THEN S2= 6
1050 PLOT 3,0,22:PRINT "CURRENT OPTION=";S2:PLOT 3,0,24:PRINT "1. 6 AM TO 6 PM":PLOT 3,40,24
1060 PRINT "2. 6 AM TO 11 PM":PLOT 3,0,26:PRINT "3. 24 HOURS":PLOT 3,40,26:INPUT "OPTION? ";S2(1)
1070 GOSUB 50:S2(1)= INT (S2(1)):IF S2(1)< 1OR S2(1)> 3GOTO 1280
1080 IF S2(1)= 1THEN S2(1)= 12
1090 IF S2(1)= 2THEN S2(1)= 17
1100 IF S2(1)= 3THEN S2(1)= 24
1110 GOTO 910
1120 PLOT 3,0,20:PRINT "OPTIONS FOR DAYS OF SERVICE ARE:":IF S3= 6THEN S3= 1:GOTO 1140
1130 S3= 2
1140 PLOT 3,0,22:PRINT "CURRENT OPTION=";S3:PLOT 3,0,24:PRINT "1. MON. - SAT."
1150 PLOT 3,0,26:PRINT "2. MON. - SUN."
1160 PLOT 3,40,26:INPUT "NEW DAYS= ";S3(1):GOSUB 50
1170 S3(1)= INT (S3(1)):IF S3(1)< 1OR S3(1)> 2GOTO 1290
1180 S3(1)= 7:IF S3(1)= 1THEN S3(1)= 6
1190 GOTO 910
1200 PLOT 3,0,20:PRINT "FARE MAY BE CHANGED IN NICKEL UNITS WITH A"
1210 PRINT "MINIMUM FARE= $.25; MAX.= $1.00"
1220 PLOT 3,0,24:PRINT "DO NOT ENTER DOLLAR SIGN."
1230 PLOT 3,0,26:PRINT "CURRENT FARE=";S4:PLOT 3,40,26:INPUT "NEW FARE= ";S4$
1240 GOSUB 50:IF RIGHT$ (S4$,1)< > "0"AND RIGHT$ (S4$,1)< > "5"GOTO 1310
1250 S4(1)= VAL (S4$):IF S4(1)< .25OR S4(1)> 1GOTO 1300
1260 GOTO 910
1270 PLOT 3,0,29:PRINT "NUMBER OUTSIDE RANGES":PLOT 3,0,22,11:GOTO 970
1280 PLOT 3,0,29:PRINT "OPTION MUST BE 1,2, OR 3":PLOT 3,40,26:PRINT C$:GOTO 1050
1290 PLOT 3,0,29:PRINT "OPTION MUST BE 1 OR 2":PLOT 3,40,26:PRINT C$:GOTO 1150
1300 PLOT 3,0,29:PRINT "NUMBER OUTSIDE RANGES":PLOT 3,40,26:PRINT C$:GOTO 1230
1310 PLOT 3,0,29:PRINT "FARE MUST BE NICKEL INCREMENTS":PLOT 3,40,26:PRINT C$:GOTO 1230
1320 S6= 0:IF S1(1)= 0AND S2(1)= 0AND S3(1)= 0AND S4(1)= 0GOTO 1460
1330 IF S3(1)AND S3(1)- S3= 5THEN S6= S6+ ((FN XR(15000)+ 75000)* S1)
1340 IF S3(1)AND S3(1)- S3= 7THEN S6= S6+ ((FN XR(25000)+ 9E04)* S1)
1350 IF S3(1)AND S3(1)- S3= 12THEN S6= S6+ ((FN XR(3E04)+ 11E04)* S1)
1360 IF S3(1)AND S3- S3(1)= 5THEN S6= S6- ((FN XR(15000)+ 75000)* S1)
1370 IF S3(1)AND S3- S3(1)= 7THEN S6= S6- ((FN XR(25000)+ 9E04)* S1)
1380 IF S3(1)AND S3- S3(1)= 12THEN S6= S6- ((FN XR(3E04)+ 11E04)* S1)
1390 IF S1(1)THEN S6= S6+ (((100+ FN XR(120))* 500)* (S1(1)- S1))
1400 IF S2(1)> 0THEN S6= S6+ (FN XR(1E04)+ 1500)* (S2(1)- S2)
1410 IF S4(1)AND S4(1)> S4THEN S6= S6- (((S4(1)- S4)/ 5)* 2000)
1420 IF S1(1)> 0THEN S1= S1(1)
1430 IF S2(1)> 0THEN S2= S2(1)
1440 IF S3(1)> 0THEN S3= S3(1)
1450 IF S4(1)> 0THEN S4= S4(1)
1460 S1(1)= 0:S2(1)= 0:S3(1)= 0:S4(1)= 0:PLOT 6,2
1470 IF YR= 3OR YR= 7GOTO 1490
1480 GOTO 2250
1490 B9= B1:B8= DS:B1= 2E06:IF YR= 3THEN B1= 15E05
1500 PLOT 12:PRINT TAB( 15)"STREET FUND BOND PROPOSAL":PRINT
1510 PRINT "YOU MAY PROPOSE BONDING UP TO $";B1;" SUBJECT TO"
1520 PRINT "APPROVAL OF ";A8$;" AND A VOTE OF THE CITIZENS."
1530 PRINT "HOW MUCH DO YOU PROPOSE (IN 1000'S)? "
1540 PRINT :INPUT "TYPE '0' IF NONE ";Z
1550 IF Z= 0GOTO 2240
1560 Z= Z* 1000:IF Z< 0OR Z> B1THEN 1450
1570 B1= Z
1580 IF CV< 8THEN B1= B1- FN XR(35)* 1E04
1590 IF CV< 10THEN B1= B1- FN XR(20)* 1E04
1600 PRINT :PRINT A8$;" APPROVED THE REFERENDUM FOR $";B1
1610 PRINT "EACH YEAR.":PRINT :PRINT :GOSUB 60
1620 PLOT 12,6,7:PRINT "THE COALITION OF NEIGHBORHOOD ASSOCIATIONS HAS ASKED"
1630 PRINT "YOU TO MAKE THE FOLLOWING PLEDGES FOR THE NEXT 3 YEARS."
1640 PLOT 6,5:B2= T(4,0)- 2:IF T(4,YR)< T(4,0)THEN B2= T(4,YR)- 2
1650 IF B2< 1THEN B2= 1
1660 B2= T(5,0)- 2:IF T(5,YR)< T(5,0)THEN B3= T(5,YR)- 2
1670 IF B3< 1THEN B3= 1
1680 B4= 20:IF G1> 22THEN B4= 44- G1
1690 B5= 6:IF G3> 11THEN B5= 16- G3
1700 PRINT TAB( 5)"1. IMPROVE STREET CONDITION INDEX TO";B2
1710 PRINT TAB( 5)"2. IMPROVE SAFETY INDEX TO";B3
1720 PRINT TAB( 5)"3. CONSTRUCT";B4;" MILES OF PRIMARIES"
1730 PRINT TAB( 5)"4. CONSTRUCT";B5;" MILES OF INTERSTATES"
1740 PRINT :PLOT 3,0,24:PRINT "PLEDGE 1";TAB( 15)"PLEDGE 2";TAB( 30)"PLEDGE 3";TAB( 45)"PLEDGE 4"
1750 PLOT 6,4,3,0,22:PRINT "WILL YOU MAKE ANY OF THEM (Y/N)? "
1760 PLOT 3,9,24:PRINT "   ":PLOT 3,9,24:INPUT Z$
1770 Z$= LEFT$ (Z$,1):IF Z$< > "Y"AND Z$< > "N"GOTO 1750
1780 IF Z$= "N"THEN B2= 0
1790 PLOT 3,24,24:PRINT "   ":PLOT 3,24,24:INPUT Z$
1800 Z$= LEFT$ (Z$,1):IF Z$< > "Y"AND Z$< > "N"GOTO 1790
1810 IF Z$= "N"THEN B3= 0
1820 PLOT 3,39,24:PRINT "   ":PLOT 3,39,24:INPUT Z$
1830 Z$= LEFT$ (Z$,1):IF Z$< > "Y"AND Z$< > "N"GOTO 1820
1840 IF Z$= "N"THEN B4= 0
1850 PLOT 3,54,24:PRINT "   ":PLOT 3,54,24:INPUT Z$
1860 Z$= LEFT$ (Z$,1):IF Z$< > "Y"AND Z$< > "N"GOTO 1850
1870 IF Z$= "N"THEN B5= 0
1880 PLOT 6,2:GOSUB 60
1890 PLOT 12,6,5:PRINT TAB( 18)"BOND ELECTION RESULTS"
1900 PRINT :PRINT "WARD";TAB( 10)"YES";TAB( 20)"NO";TAB( 35)"TOT. YES";TAB( 50)"TOT. NO"
1910 PRINT :V5= 0:V6= 0
1920 V1= 4000:IF CV> 9THEN V1= 5000
1930 IF T(4,YR)< T(4,A)AND T(4,YR)< T(4,0)THEN V1= V1+ 500
1940 IF T(5,YR)< T(5,A)AND T(5,YR)< T(5,0)THEN V1= V1+ 500
1950 IF YR= 7THEN 1980
1960 IF B1< 11E06THEN V1= V1+ 500
1970 GOTO 1990
1980 IF B1< 16E06THEN V1= V1+ 500
1990 IF B2> 0THEN V1= V1+ 500
2000 IF B3> 0THEN V1= V1+ 500
2010 IF B4> 0THEN V1= V1+ 500
2020 IF B5> 0THEN V1= V1+ 500
2030 V2= FN XR(5)
2040 FOR X= 1TO 5
2050 IF X= V2GOTO 2080
2060 V3= V1+ FN XR(11000)
2070 GOTO 2100
2080 V3= V1/ 2+ FN XR(12000)
2090 IF V3< 3000THEN V3= 4000
2100 V4= 21000- V3:V5= V5+ V3:V6= V6+ V4
2110 PRINT TAB( 2)X;TAB( 9)V3;TAB( 19)V4;TAB( 35)V5;TAB( 50)V6
2120 NEXT X
2130 IF V5< = V6GOTO 2180
2140 PRINT :PRINT "CONGRATULATIONS.  THE BOND ISSUE WAS APPROVED"
2150 DS= PT* .3:PRINT "YOUR ANNUAL DEBT PAYMENT WILL BE $";DS
2160 TB(9,YR)= TB(9,YR)+ B1:B= B- 10:DS= DS+ B8:B1= B1+ B9
2170 GOSUB 60:GOTO 2250
2180 PRINT "THE REFERENDUM FAILED."
2190 IF V6/ (V5+ V6)< (55+ FN XR(15))* .01GOTO 2230
2200 PRINT "BECAUSE OF THE MARGIN OF DEFEAT, YOU HAVE LOST"
2210 PRINT "THE VOTE OF A COMMISSIONER.":GOSUB 30
2220 IF CV< 6GOTO 6370
2230 B1= B9:B2= 0:B3= 0:B4= 0:B5= 0
2240 GOSUB 60
2250 PLOT 12,6,3:PRINT TAB( 18)"PROPERTY TAX LEVY":PRINT
2260 M5= (S1* S2* S3* 312* S)+ M9:M2= M2+ M5* .1:B(1,YR)= B(1,YR)+ (S4* S(1,YR))+ ((M2+ M5)/ 2)
2270 PRINT TAB( 30)"STREET FUND";TAB( 45)"TRANSIT AUTHORITY"
2280 PRINT "OPERATING NEEDS";TAB( 30)"$";MN+ SN+ DS;TAB( 45)"$";M2+ M5
2290 PRINT "NON-TAX REVENUE";TAB( 30);"$";TB(8,YR);TAB( 45);"$";B(1,YR)
2300 X1= M2+ M5- B(1,YR):IF M2+ M5- B(1,YR)< 0THEN X1= 0
2310 PRINT "PROPERTY TAX NEEDED (MILLS)";TAB( 30);"$";MN+ SN+ DS- TB(8,YR);TAB( 45);"$";X1
2320 TN= INT (((MN+ SN+ DS+ X1- TB(8,YR))/ PT)* 10)* .1:PRINT :PRINT "YIELD OF 1 MILL=";"$";PT
2330 PRINT :PRINT "PROPERTY TAX NEEDED (IN MILLS)=";TN
2340 PLOT 3,0,20:INPUT "WHAT PROPERTY TAX LEVY (0-10 MILLS) DO YOU PROPOSE? ";TB(2,YR)
2350 GOSUB 50
2360 IF TB(2,YR)> = 0AND TB(2,YR)< = 10GOTO 2380
2370 PLOT 3,0,29:PRINT "YOU ARE OUTSIDE SET LIMITS";:PLOT 3,0,20:PRINT SPC( 63)"":GOTO 2340
2380 IF TB(2,YR)< = TB(2,YR- 1)GOTO 2550
2390 X1= 0:X2= 0
2400 FOR X= 1TO 11
2410 IF CV> 9GOTO 2440
2420 X3= FN XR(8):IF X< = CVTHEN X3= FN XR(5)
2430 GOTO 2470
2440 IF X< = 2THEN X3= FN XR(4)
2450 IF X> 2AND X< = CVTHEN X3= FN XR(5)
2460 IF X> CVTHEN X3= FN XR(8)
2470 IF X3< = 3THEN X1= X1+ 1:GOTO 2490
2480 X2= X2+ 1
2490 NEXT X
2500 IF X1> = 6GOTO 2530
2510 IF TB(2,YR)< = TNGOTO 2530
2520 TB(2,YR)= TB(2,YR)- (.1* (X2+ 1))
2530 IF X1> = 6GOTO 2550
2540 IF TB(2,YR)> = TN+ 2AND X1< 10THEN TB(2,YR)= TB(2,YR)- (.2* (X2+ 1))
2550 PLOT 6,7,3,0,21:PRINT :PRINT A8$;" HAS APPROVED A LEVY OF";TB(2,YR);" MILLS"
2560 PLOT 3,0,24:INPUT "HOW MANY MILLS FOR THE STREET FUND? ";T8:GOSUB 50
2570 IF T8< = TB(2,YR)GOTO 2600
2580 PLOT 3,0,29:PRINT "YOU CAN'T ALLOCATE MORE THAN AUTHORIZED"
2590 PLOT 3,0,24:PRINT SPC( 50)"":GOTO 2560
2600 TB(8,YR)= TB(8,YR)+ PT* T8- DS:B(1,YR)= B(1,YR)+ (PT* (TB(2,YR)- T8))
2610 PLOT 12:C= O:GOTO 2630
2620 C= 1
2630 PLOT 12,6,4:PRINT TAB( 10)"STREET FUND BUDGET DECISIONS FOR YEAR";YR:PRINT
2640 PRINT "OPERATIONS:";TAB( 30)"CONSTRUCTION:"
2650 PRINT TAB( 2)"AVAILABLE:   $";TB(8,YR);TAB( 32)"AVAILABLE:   $";TB(9,YR):PRINT
2660 PRINT TAB( 2)"MAINT. NEED= $";MN;TAB( 32)"COST/HALF-MILE:"
2670 PRINT TAB( 2)"SAFETY NEED= $";SN;TAB( 32)"PRIMARIES=   $";CI* .2
2680 PRINT TAB( 32)"INTERSTATES= $";CI
2690 PRINT :IF C= 1GOTO 2830
2700 PLOT 6,6:PRINT "YOU MAY TRANSFER UP TO";B;" % FROM AN ACCOUNT"
2710 PRINT TAB( 10)"1. OPERATIONS TO CONSTRUCTION"
2720 PRINT TAB( 10)"2. CONSTRUCTION TO OPERATIONS"
2730 PRINT TAB( 10)"3. NO TRANSFER"
2740 PLOT 3,10,14:INPUT "YOUR CHOICE: ";Z:IF Z< > 1AND Z< > 2AND Z< > 3GOTO 2630
2750 IF Z= 3GOTO 2620
2760 PRINT :INPUT "HOW MUCH WILL YOU TRANSFER (IN 1000'S)? ";T
2770 T= T* 1000
2780 IF Z= 1AND T> TB(8,YR)/ (B* .01)GOTO 2760
2790 IF Z= 2AND T> TB(9,YR)/ (B* .01)GOTO 2760
2800 IF Z= 2GOTO 2820
2810 TB(8,YR)= TB(8,YR)- T:TB(9,YR)= TB(9,YR)+ T:GOTO 2620
2820 TB(8,YR)= TB(8,YR)+ T:TB(9,YR)= TB(9,YR)- T:GOTO 2620
2830 PLOT 6,2:PRINT "ENTER CONSTRUCTION BY # OF 1/2-MILE UNITS"
2840 PRINT "ENTER MAINTENANCE AND SAFETY BY 1000 DOLLAR UNITS."
2850 PRINT "DO NOT USE COMMAS OR DOLLAR SIGNS!"
2860 PRINT :PRINT TAB( 10)"PRIMARIES";TAB( 20)"INTERSTATES";TAB( 36)"MAINTENANCE";TAB( 53)"SAFETY"
2870 PRINT "LAST YR.";TAB( 13);PC;TAB( 23);IC;
2880 PRINT TAB( 35)"$";TB(6,A);TAB( 50);"$";TB(7,A)
2890 PLOT 3,0,15:PRINT "THIS YEAR":PLOT 3,13,15:INPUT PC
2900 GOSUB 50
2910 IF INT (PC)< > PCGOTO 3090
2920 IF G1+ PC/ 2> 44GOTO 3110
2930 PLOT 3,23,15:INPUT IC:GOSUB 50
2940 IF INT (IC)< > ICGOTO 3120
2950 IF T(3,YR)+ IC/ 2> 16GOTO 3140
2960 IF (PC* CI* .2)+ IC* CI> TB(9,YR)GOTO 3150
2970 PLOT 3,36,15:INPUT T1:T1= T1* 1000:GOSUB 50
2980 IF LEN (STR$ (T1))> LEN (STR$ (MN))+ 1OR T1< 1E05THEN GOSUB 3170:GOTO 3000
2990 GOTO 3020
3000 IF Z$= "Y"THEN 3020
3010 Z$= "Y":PLOT 3,36,15:PRINT D$:GOTO 2970
3020 PLOT 3,51,15:INPUT T2:GOSUB 50:T2= T2* 1000
3030 IF LEN (STR$ (T2))> LEN (STR$ (SN))OR T2< 1E05THEN GOSUB 3170:GOTO 3050
3040 GOTO 3070
3050 IF Z$= "Y"GOTO 3070
3060 Z$= "Y":PLOT 3,51,15:PRINT D$:GOTO 3020
3070 IF T1+ T2> TB(8,YR)GOTO 3240
3080 GOTO 3260
3090 PLOT 3,0,29:PRINT "ENTER A WHOLE NUMBER."
3100 PLOT 3,9,26:PRINT C$:GOTO 2890
3110 PLOT 3,0,29:PRINT "YOU CAN'T BUILD THAT MANY MORE UNITS":GOTO 3100
3120 PLOT 3,0,29:PRINT "ENTER A WHOLE NUMBER."
3130 PLOT 3,19,26:PRINT C$:GOTO 2930
3140 PLOT 3,0,29:PRINT "YOU CAN'T BUILD THAT MANY MORE UNITS":GOTO 3130
3150 PLOT 3,0,29:PRINT "CONSTRUCTION PROGRAM EXCEEDS BUDGET."
3160 PLOT 3,13,15:PRINT C$:PLOT 3,23,15:PRINT C$:GOTO 2890
3170 GOSUB 50:GOSUB 40
3180 IF Z$< > "Y"AND Z$< > "N"GOTO 3170
3190 RETURN
3200 GOSUB 50:GOSUB 40
3210 IF Z$< > "Y"AND Z$< > "N"GOTO 3200
3220 IF Z$= "Y"GOTO 3060
3230 PLOT 3,53,26:PRINT D$:GOTO 3020
3240 PLOT 3,0,29:PRINT "MAINTENANCE AND SAFETY BUDGET EXCEEDS FUNDS"
3250 PLOT 3,36,15:PRINT D$:PLOT 3,51,15:PRINT D$:GOTO 2970
3260 TB(6,YR)= T1:TB(7,YR)= T2
3270 G1= G1+ PC/ 2:T(2,YR)= T(2,YR)+ PC/ 2:T(3,YR)= T(3,YR)+ IC/ 2
3280 TB(8,YR)= TB(8,YR)- TB(6,YR)- TB(7,YR)
3290 TB(9,YR)= TB(9,YR)- PC* CI* .2- IC* CI
3300 GOSUB 60
3310 T(4,YR)= T(4,YR)- (INT (((TB(6,YR)- MN)/ MN)* 18)* .1)
3320 IF T(4,YR)< 1THEN T(4,YR)= 1
3330 T(5,YR)= T(5,YR)- (INT (((TB(7,YR)- SN)/ SN)* 18)* .1)
3340 IF T(4,YR)> T(4,A)THEN T(5,YR)= T(5,YR)+ .2
3350 IF T(5,YR)< 1THEN T(5,YR)= 1
3360 PLOT 12:C= 0:GOTO 3380
3370 C= 1
3380 PLOT 12,6,6:PRINT TAB( 15)"TRANSIT BUDGET FOR YEAR";YR:PRINT
3390 PRINT "OPERATIONS";TAB( 33)"BUS FLEET"
3400 PRINT TAB( 2)"AVAILABLE:    $";B(1,YR);TAB( 35)"AVAILABLE:   $";B(2,YR):PRINT
3410 PRINT TAB( 2)"MAINT. NEED=  $";M2;TAB( 35)"(COST PER BUS)"
3420 PRINT TAB( 2)"OPERAT. NEED= $";M5;TAB( 35)"ACQUISITION= $";P1
3430 PRINT TAB( 35)"SALE=        $";P2
3440 IF C= 1GOTO 3600
3450 IF GG> 0THEN PLOT 3,0,20:PRINT "BECAUSE OF THE FEDERAL GRANT YOU CAN'T TRANSFER FROM"
3460 IF GG> 0THEN PRINT "OPERATIONS TO THE BUS FLEET":FOR X= 1TO 750:NEXT X:GOTO 3530
3470 PLOT 3,0,20:PRINT "YOU MAY TRANSFER UP TO 25% FROM OPERATONS TO ACQUISITION"
3480 PLOT 3,0,21:PRINT :INPUT "HOW MUCH DO YOU WISH TO TRANSFER (IN 1000'S)? ";Z
3490 Z= Z* 1000:IF Z< 0OR Z> B(1,YR)/ 4GOTO 3510
3500 GOTO 3520
3510 PLOT 28,11:GOTO 3470
3520 B(2,YR)= B(2,YR)+ Z:B(1,YR)= B(1,YR)- Z
3530 PLOT 3,0,24:INPUT "HOW MANY BUSES WILL YOU SELL? ";NB:NB= INT (NB)
3540 IF NB> S(5,YR)OR NB< 0GOTO 3560
3550 GOTO 3570
3560 PLOT 28,11:GOTO 3530
3570 IF NB= 0GOTO 3370
3580 BF= BF- S(2,YR)* 2* NB:S(5,YR)= S(5,YR)- NB:M2= M1* S(5,YR)+ M3* BF
3590 B(2,YR)= B(2,YR)+ NB* P2:GOTO 3370
3600 PLOT 6,1:PRINT :PRINT "ENTER BUDGETS IN 1000 DOLLAR UNITS."
3610 PRINT :PRINT TAB( 22)"MAINTENANCE";TAB( 36)"OPERATIONS";TAB( 50)"NEW BUSES"
3620 PRINT "LAST YEAR";TAB( 20);"$";BD;TAB( 35);"$";BE;TAB( 53);BN
3630 PRINT "THIS YEAR"
3640 PLOT 3,21,13:INPUT BD:GOSUB 50:BD= BD* 1000
3650 IF BD< 0THEN GOSUB 4040
3660 IF BD< 0GOTO 3640
3670 IF BD< 1E05THEN GOSUB 3170
3680 IF BD< 1E05GOTO 3700
3690 GOTO 3720
3700 IF Z$= "Y"GOTO 3720
3710 Z$= "Y":PLOT 3,21,13:PRINT D$:GOTO 3640
3720 IF LEN (STR$ (BD))> LEN (STR$ (M2))+ 1GOTO 3940
3730 PLOT 3,36,13:INPUT BE:GOSUB 50:BE= BE* 1000
3740 IF BE< 0THEN GOSUB 4040
3750 IF BE< 0GOTO 3730
3760 IF BE< 1E05THEN GOSUB 3170
3770 IF BE< 1E05GOTO 3790
3780 GOTO 3810
3790 IF Z$= "Y"GOTO 3810
3800 PLOT 3,36,13:PRINT D$:GOTO 3730
3810 IF LEN (STR$ (BE))> LEN (STR$ (M5))+ 1GOTO 3970
3820 IF BD+ BE> B(1,YR)GOTO 4010
3830 PLOT 3,53,13:INPUT BN:GOSUB 50
3840 IF BN> 100- S(5,YR)GOTO 4030
3850 IF BN< 0THEN GOSUB 4040
3860 IF BN> = 0GOTO 3890
3870 PLOT 3,53,13:PRINT C$:GOTO 3830
3880 IF INT (BN)< > BNGOTO 4070
3890 IF BN* P1> B(2,YR)GOTO 4050
3900 B(2,YR)= B(2,YR)- P1* BN:S(5,YR)= S(5,YR)+ BN:BF= BF- BN
3910 BF= BF+ S(5,YR):S(2,YR)= INT (BF/ S(5,YR)* 10)* .1
3920 B(1,YR)= B(1,YR)- (BD+ BE)
3930 GOTO 4080
3940 GOSUB 50:GOSUB 40
3950 IF Z$< > "Y"AND Z$< > "N"GOTO 3940:IF Z$= "Y"GOTO 3730
3960 PLOT 3,21,13:PRINT D$:GOTO 3640
3970 GOSUB 50:GOSUB 40
3980 IF Z$< > "Y"AND Z$< > "N"GOTO 3970
3990 IF Z$= "Y"GOTO 3820
4000 PLOT 3,36,13:PRINT D$:GOTO 3730
4010 PLOT 3,0,29:PRINT "OPERATIONS AND MAINTENANCE BUDGETS EXCEED FUNDS"
4020 PLOT 3,21,13:PRINT D$:PLOT 3,36,13:PRINT D$:GOTO 3640
4030 PLOT 3,0,29:PRINT "YOU CAN PURCHASE ONLY";100- S(5,YR);" BUSES":GOTO 3830
4040 PLOT 3,0,29:PRINT "YOU CAN'T ENTER A NEGATIVE NUMBER":RETURN
4050 PLOT 3,0,29:PRINT "PROPOSED ACQUISITION EXCEEDS BUDGET"
4060 PLOT 3,53,13:PRINT C$:GOTO 3830
4070 PLOT 3,0,29:PRINT "YOU MUST ENTER A WHOLE NUMBER":PLOT 3,52,24:PRINT C$:GOTO 3830
4080 S(3,YR)= S(3,YR)- INT (((BD- M2)/ M2)* 18)* .1
4090 IF S(2,YR)> S(2,A)THEN S(3,YR)= S(3,YR)+ .2
4100 IF S(3,YR)< 1THEN S(3,YR)= 1
4110 S(4,YR)= S(4,YR)- INT (((BE- M5)/ M5)* 81)* .1
4120 IF S(3,YR)> S(3,A)THEN S(3,YR)= S(3,YR)+ .2
4130 IF S(5,YR)/ S1< 3THEN S(4,YR)= S(4,YR)+ .2
4140 IF S(4,YR)< 1THEN S(4,YR)= 1
4150 S(1,YR)= (S(1,YR)+ S6)- ((S(3,YR)+ S(4,YR)- S(3,A)- S(4,A))* S(1,YR)* .01)
4160 NR= FN XR(4)+ 2:I= I* 100:IF I= 0THEN U(1)= INT (FN XR(8)+ 8):GOTO 4180
4170 U(1)= INT (FN XR(I)+ 8)
4180 PLOT 12,6,2:LS= 0
4190 PRINT :PRINT "PRESENT WAGE IS";S;" DOLLARS/HOUR"
4200 PRINT "THE UNION'S INITIAL OFFER IS FOR A";U(1);" % INCREASE"
4210 INPUT "WHAT IS YOUR RESPONSE ( % )? ";M(1)
4220 PLOT 12
4230 PRINT "PRESENT SALARY= $";S
4240 PRINT :PRINT "UNION",,"MANAGEMENT"
4250 PRINT "POSITION","POSITION":PRINT :PRINT  U(1),,M(1)
4260 FOR X= 2TO NR
4270 IF X< > NRGOTO 4300
4280 PRINT "LAST ROUND OF NEGOTIATIONS.  FAILURE"
4290 PRINT "TO SETTLE COULD RESULT IN A STRIKE."
4300 UO= U(X- 1)- M(X- 1):IF UO< > 0GOTO 4330
4310 U(X)= M(X- 1):U= U(X)
4320 GOTO 4490
4330 J= M(X- 1)- M(X- 2):IF J> = 5THEN R3= 1
4340 IF J< 5THEN R3= 2
4350 IF J< 3THEN R3= 3
4360 IF J< 1THEN R3= 4
4370 IF UO> 5THEN U(X)= U(X- 1)- (FN XR(40)* .1)/ R3
4380 IF UO> 10OR UO< 5THEN U(X)= U(X- 1)- (FN XR(60)* .1)/ R3
4390 IF UO> 15THEN U(X)= U(X- 1)- (FN XR(80)* .1)/ R3
4400 IF UO> 20THEN U(X)= U(X- 1)- (FN XR(100)* .1)/ R3
4410 IF U(X)= U(X- 1)THEN U(X)= U(X- 1)- .5
4420 IF U(X)< = M(X- 1)THEN U(X)= M(X- 1)
4430 U(X)= INT (U(X)* 100)* .01
4440 U= U(X):PRINT U(X),
4450 IF U(X)= M(X- 1)GOTO 4490
4460 PRINT TAB( 16);:INPUT M(X):IF M(X)> = U(X)GOTO 4490
4470 NEXT X
4480 IF M(NR)< > U(NR)GOTO 4530
4490 S= INT (S* (100+ U))* .01
4500 PRINT "YOU HAVE AGREED ON A ";U;" % WAGE INCREASE."
4510 PRINT "YOUR HOURLY WAGE IS NOW $";S
4520 GOTO 4880
4530 IF (U(NR)- M(NR))* RND (1)> .5GOTO 4560
4540 U(NR)= M(NR):U= U(NR)
4550 GOTO 4490
4560 PLOT 12,6,1:FOR X= 40TO 80:PLOT 2,X,112,255:NEXT X
4570 FOR Y= 111TO 41STEP - 1:PLOT 2,40,Y,80,Y,255:NEXT Y
4580 FOR X= 40TO 80:PLOT 2,X,40,255:NEXT X
4590 FOR Y= 8TO 40:PLOT 2,60,Y,255:NEXT Y
4600 PLOT 6,3:PLOT 3,26,7:PRINT "WORKER'S":PLOT 3,27,9:PRINT "LOCAL"
4610 PLOT 3,27,11:PRINT "10200"
4620 PLOT 3,29,17:PLOT 6,71:PRINT "0N":PLOT 3,27,19:PRINT "STRIKE"
4630 PLOT 6,2
4640 FOR X= 1TO 1000:NEXT X:M(7)= M(NR)- M(1):U(7)= U(1)- U(NR):DP= U(NR)- M(NR)
4650 SS(1)= DP* ((FN XR(6)+ 3)* .1):IF M(7)> U(7)THEN SS(1)= DP* (FN XR(6)* .1)
4660 SS(2)= M(NR)+ SS(1):U= INT (SS(2)* 100)* .01
4670 LS= FN XR(5)+ FN XR(DP+ 1)
4680 PLOT 12:PRINT "THE STRIKE LASTED FOR";LS;" DAYS."
4690 PRINT "THE ARBITRATOR HAS OFFERRED A SETTLEMENT OF";U;" %."
4700 PRINT "THIS RESULTS IN A WAGE OF";
4710 S= INT (S* (100+ U))* .01:PRINT S
4720 PRINT "AS A RESULT OF THE STRIKE,":PRINT
4730 X1= FN XR(4)* .1:IF LS> = 7THEN X1= FN XR(7)* .1
4740 T(4,YR)= T(4,YR)+ X1:PRINT TAB( 5);T$(4);" HAS INCREASED BY";X1
4750 X1= FN XR(4)* .1:IF LS> = 7THEN X1= FN XR(7)* .1
4760 T(5,YR)= T(5,YR)+ X1:PRINT TAB( 5);T$(5);" HAS INCREASED BY";X1
4770 IF PC< 2GOTO 4820
4780 IF LS> = 7THEN PC= PC- 2
4790 GOTO 4810
4800 PRINT TAB( 5)"CONSTRUCTION PROGRAM LOST 1 MILE":GOTO 4740
4810 PC= PC- 1:PRINT "CONSTRUCTION PROGRAM LOST 1/2 MILE"
4820 PRINT
4830 X1= FN XR(4)* .1:IF LS> = 7THEN X1= FN XR(7)* .1
4840 S(3,YR)= S(3,YR)+ X1:PRINT TAB( 5);S$(3);" HAS INCREASED BY";X1
4850 X1= FN XR(4)* .1:IF LS> = 7THEN X1= FN XR(7)* .1
4860 S(4,YR)= S(4,YR)+ X1:PRINT TAB( 5);S$(4);" HAS INCREASED BY";X1
4870 PRINT :GOTO 4880
4880 GOSUB 60
4890 PLOT 12:PRINT TAB( 10)"STREET FUND PERFORMANCE FOR YEAR";YR
4900 PRINT
4910 PRINT TAB( 30)"YEAR";YR;TAB( 40)"YEAR";A;TAB( 50)"PLAN"
4920 PRINT
4930 FOR X= 2TO 5
4940 PRINT T$(X);TAB( 30)T(X,YR);TAB( 40)T(X,A);TAB( 50)T(X,11)
4950 NEXT X
4960 PRINT :INPUT "TYPE '1' TO REVIEW STREET MAP, ELSE PRESS 'RETURN' ";Z
4970 PLOT 12,6,7
4980 IF Z< > 1GOTO 5330
4990 G2= 0:G4= 0:PLOT 12
5000 FOR X= 1TO 8
5010 G5= 2:IF X> 5THEN G5= 64
5020 G6= .25:IF X> 5THEN G6= .5
5030 IF X= 4OR X= 6GOTO 5100
5040 FOR Y= A(X,1)TO A(X,2)STEP G5
5050 AY= INT (Y/ 64):AX= Y- (AY* 64)
5060 G2= G2+ G6
5070 IF G2< = G1THEN PLOT 3,AX,AY,43
5080 IF G2> G1THEN PLOT 3,AX,AY,45
5090 GOTO 5150
5100 FOR Y= A(X,1)TO A(X,2)STEP G5
5110 AY= INT (Y/ 64):AX= Y- (AY* 64)
5120 G4= G4+ G6
5130 IF G4< = T(3,YR)THEN PLOT 3,AX,AY,42
5140 IF G4> T(3,YR)THEN PLOT 3,AX,AY,35
5150 NEXT Y
5160 NEXT X
5170 PLOT 6,1,3,13,0:PRINT "I-196"
5180 PLOT 3,30,0:PRINT "ASH"
5190 PLOT 3,46,0:PRINT "OAK"
5200 PLOT 3,0,2:PRINT "1ST"
5210 PLOT 3,0,6:PRINT "2ND"
5220 PLOT 3,0,10:PRINT "3RD"
5230 PLOT 3,0,12:PRINT "I-465"
5240 PLOT 3,0,14:PRINT "4TH"
5250 PLOT 3,50,3:PRINT "PRIMARIES"
5260 PLOT 3,55,4:PRINT "+=";G1
5270 PLOT 3,55,5:PRINT "-=";44- G1
5280 PLOT 3,50,7:PRINT "INTERSTATES"
5290 PLOT 3,55,8:PRINT "*=";T(3,YR):PRINT
5300 PLOT 3,55,9:PRINT "#=";16- T(3,YR)
5310 PLOT 3,0,29:PRINT "+,* = COMPLETE   -,# = INCOMPLETE"
5320 PLOT 3,38,29:INPUT "PRESS 'RETURN' ";Z
5330 PLOT 12,6,4:PRINT TAB( 12)"TRANSIT PERFORMANCE REVIEW FOR YEAR";YR:PRINT
5340 PRINT TAB( 15)"YEAR";YR;TAB( 30)"YEAR";A;TAB( 45)"PLAN"
5350 FOR X= 1TO 4
5360 IF X> 1GOTO 5380
5370 PRINT S$(X);TAB( 15);S(X,YR);TAB( 30);S(X,A);TAB( 45);S(X,11):GOTO 5390
5380 PRINT S$(X);TAB( 15);S(X,YR);TAB( 30);S(X,A);TAB( 45);S(X,11)
5390 NEXT X
5400 PRINT S$(5);TAB( 15);S(5,YR);TAB( 30);S(5,A)
5410 GOSUB 60:PLOT 12
5420 IF T(2,YR)< T(2,11)GOTO 5640
5430 IF T(3,YR)< T(3,11)GOTO 5640
5440 IF T(4,YR)> T(4,11)GOTO 5640
5450 IF T(5,YR)> T(5,11)GOTO 5640
5460 IF S(1,YR)< S(1,11)GOTO 5640
5470 IF S(2,YR)> S(2,11)GOTO 5640
5480 IF S(3,YR)> S(3,11)GOTO 5640
5490 IF S(4,YR)> S(4,11)GOTO 5640
5500 PLOT 12,6,5:PRINT :PRINT "CONGRATULATIONS!"
5510 PRINT :PRINT "YOU SUCCESSFULLY COMPLETED"
5520 PRINT "THE TRANSPORTATION PLAN IN":PRINT YR;"YEARS.":PRINT
5530 IF YR> 7GOTO 5560
5540 PRINT "YOUR PERFORMANCE HAS BEEN SO GOOD THAT YOU HAVE BEEN ASKED"
5550 PRINT "TO BECOME THE NEW TRANSPORTATION SECRETARY.":GOTO 5630
5560 IF YR= 10GOTO 5600
5570 PRINT "BECAUSE OF YOUR PERFORMANCE"
5580 PRINT "YOU HAVE BEEN ASKED TO BECOME THE TRANSPORTATION DIRECTOR"
5590 PRINT "OF NEW YORK CITY.":GOTO 5630
5600 PRINT "YOU HAVE BEEN GIVEN A LARGE PAY RAISE"
5610 PRINT "AND HAVE BEEN ASKED TO CONTINUE AS"
5620 PRINT "TRANSPORTATION DIRECTOR OF RIVER CITY."
5630 END
5640 PLOT 12,6,6:IF YR= 1GOTO 650
5650 PRINT TAB( 15)"PERFORMANCE EVALUATION FOR YEAR";YR:PRINT
5660 IF T(4,YR)< T(4,A)+ .1OR T(4,A)< T(4,D)+ .1GOTO 5680
5670 GOSUB 30:PRINT A1$;" WORSENED ";A5$
5680 IF T(5,YR)< T(5,A)+ .1OR T(5,A)< T(5,D)+ .1GOTO 5700
5690 GOSUB 30:PRINT A2$;" WORSENED ";A5$
5700 IF T(4,YR)< T(4,A)* 1.35GOTO 5720
5710 GOSUB 30:PRINT A1$;" WORSENED BY OVER 35% ";A6$
5720 IF T(5,YR)< T(5,A)* 1.4GOTO 5740
5730 GOSUB 30:PRINT A2$;" WORSENED BY OVER 40% ";A6$
5740 IF T(2,YR)> = T(2,D)+ 5GOTO 5760
5750 GOSUB 30:PRINT "PRIMARY STREET CONSTRUCTION IS NOT PROGRESSING WELL."
5760 IF YR< 7OR YR= 10GOTO 5790
5770 IF T(3,YR)> = YR* 2- 4OR G1> = YR* 3+ 13GOTO 5790
5780 GOSUB 30:PRINT "THERE IS FEELING YOU WILL NOT COMPLETE THE STREET PLAN."
5790 IF T(4,YR)< T(4,A)OR T(5,YR)< T(5,A)OR T(2,YR)> T(2,D)+ 4GOTO 5810
5800 GOSUB 30:PRINT A4$;" STREET FUND PERFORMANCE."
5810 IF S(1,YR)> S(1,A)OR S(1,A)> S(1,D)GOTO 5830
5820 GOSUB 30:PRINT "BUS RIDERSHIP HAS DECLINED ";A5$
5830 IF S(2,YR)< S(2,0)+ 4GOTO 5850
5840 GOSUB 30:PRINT "THE BUS FLEET HAS BEEN ALLOWED TO DETERIORATE."
5850 IF S(3,YR)< S(3,A)+ .1OR S(3,A)< S(3,D)+ .1GOTO 5870
5860 GOSUB 30:PRINT A7$;" INCREASED ";A5$
5870 IF S(3,YR)< S(3,A)* 1.35GOTO 5890
5880 GOSUB 30:PRINT A7$;" INCREASED OVER 35% ";A6$
5890 IF S(4,YR)< S(4,A)+ .1OR S(4,A)< S(4,D)+ .1GOTO 5910
5900 GOSUB 30:PRINT A3$;" DECLINED ";A5$
5910 IF S(4,YR)< S(4,A)* 1.35GOTO 5930
5920 GOSUB 30:PRINT A3$;"DECLINED OVER 35% ";A6$
5930 X1= 0:IF S(1,YR)< S(1,A)THEN X1= .3
5940 FOR X= 2TO 4:IF S(X,YR)> S(X,A)THEN X1= X1+ .3:NEXT X
5950 IF X1< 1GOTO 5970
5960 GOSUB 30:PRINT A4$;" TRANSIT AUTHORITY PERFORMANCE."
5970 IF TB(2,YR)< 7.5OR FN XR(3)> 2GOTO 5990
5980 CV= CV- 2:PRINT "CITIZENS ARE UNHAPPY WITH THE HIGH TAX RATE."
5990 IF T(2,YR)+ T(3,YR)< T(2,D)+ T(3,D)+ 11OR T(3,YR)< T(3,A)+ 2GOTO 6010
6000 GOSUB 20:PRINT "OVERALL STREET CONSTRUCTION IS PROGRESSING WELL."
6010 IF T(4,YR)> T(4,A)- .1OR T(4,A)> T(4,D)- .1GOTO 6030
6020 GOSUB 20:PRINT A1$;" IMPROVED ";A5$
6030 IF T(4,YR)> T(4,A)* .65GOTO 6050
6040 GOSUB 20:PRINT A1$;" IMPROVED OVER 35% ";A6$
6050 IF T(5,YR)> T(5,A)- .1OR T(5,A)> T(5,D)- .1GOTO 6070
6060 GOSUB 20:PRINT A2$;" IMPROVED ";A5$
6070 IF T(5,YR)> T(5,A)* .6GOTO 6090
6080 GOSUB 20:PRINT A2$;" IMPROVED OVER 40% ";A6$
6090 IF S(2,YR)> S(2,A)- .1OR S(2,A)> S(2,D)- .1GOTO 6110
6100 GOSUB 20:PRINT "BUS FLEET AGE IMPROVED ";A5$
6110 IF S(3,YR)> S(3,A)- .1OR S(3,A)> S(3,D)- .1GOTO 6130
6120 GOSUB 20:PRINT A7$;" DECREASED ";A5$
6130 IF S(3,YR)> S(3,A)* .65GOTO 6150
6140 GOSUB 20:PRINT A7$;" BEEN REDUCED OVER 35% ";A6$
6150 IF S(4,YR)> S(4,A)- .1OR S(4,A)> S(4,D)- .1GOTO 6170
6160 GOSUB 20:PRINT A3$;" IMPROVED ";A5$
6170 IF S(4,YR)> S(4,A)* .65GOTO 6190
6180 GOSUB 20:PRINT A3$;" IMPROVED OVER 35% ";A6$
6190 X1= 0:IF S(1,YR)> S(1,A)THEN X1= .3
6200 FOR X= 2TO 4:IF S(X,YR)< S(X,A)THEN X1= X1+ .3:NEXT X
6210 IF X1< 1GOTO 6230
6220 GOSUB 20:PRINT "TRANSIT AUTHORITY PERFORMANCE IS DOING WELL."
6230 IF TB(2,YR)> 3OR FN XR(3)> 2GOTO 6250
6240 GOSUB 20:PRINT "CITIZENS ARE HAPPY WITH THE LOW TAX RATE."
6250 IF YR= 6OR YR= 9GOTO 6270
6260 GOTO 6330
6270 IF B1= 0GOTO 6330
6280 IF B2< T(4,YR)AND B2> 0GOTO 6320
6290 IF B3< T(5,YR)AND B3> 0GOTO 6320
6300 IF T(2,YR)< T(2,YR- 3)- B4AND B4> 0GOTO 6320
6310 IF T(3,YR)> T(3,YR- 3)- B5AND B5> 0GOTO 6330
6320 CV= CV- 2:PRINT "YOU RENEGED ON YOUR BOND REFERENDUM PLEDGE."
6330 GOSUB 60:PLOT 12,3,0,10::IF CV> 11THEN CV= 11
6340 IF CV< 0THEN CV= 0
6350 IF CV< 6GOTO 6370
6360 IF YR= 10GOTO 6420
6370 PRINT :PRINT "AS A RESULT OF YOUR PERFORMANCE ";A6$:PRINT :PLOT 6,6
6380 IF CV> = 6THEN PRINT A8$;" HAS VOTED";CV;" -";11- CV;" TO RETAIN YOU ANOTHER YEAR."
6390 IF CV< 6THEN PRINT A8$;" HAS VOTED TO REQUEST YOUR RESIGNATION."
6400 IF CV> = 6GOTO 6460
6410 GOTO 6470
6420 PRINT :PRINT "YOU HAVE NOT COMPLETED THE TEN-YEAR PLAN."
6430 PRINT :PRINT "HOWEVER, THE CITY COMMISSION HAS VOTED";CV;" -";11- CV
6440 PRINT "TO RETAIN YOU AS ASSISTANT TRANSPORTATION DIRECTOR."
6450 GOTO 6470
6460 PLOT 6,2:GOSUB 60:GOTO 650
6470 PLOT 3,0,25:INPUT "ANOTHER GAME? (Y/N) ";X$
6480 IF LEFT$ (X$,1)= "Y"THEN RUN 80
6490 PLOT 12:END