Listing of file='ROULET.BAS;01' on disk='vmedia/blackjack-sector.ccvf'
100 REM ** ROULETTE - JAN 3,79 - JESSEN **
105 FOR I= 1TO PEEK (33209):X= RND (1):NEXT I
110 PLOT 6,0,12,6,37,3,12,4,14
120 PRINT " C O M P U C O L O R R O U L E T T E "
130 PLOT 6,3:PRINT
140 PRINT "WELCOME TO THE COMPUCOLOR ROULETTE TABLE. PLACE YOUR BETS FOR"
150 PRINT "EACH CATAGORY BY TYPING IN THE BET AND HITTING RETURN. IF YOU"
160 PRINT "DO NOT WISH TO BET ON A CATAGORY, THEN HIT RETURN. YOU MAY SPIN"
170 PRINT "THE WHEEL AT ANY POINT BY ENTERING SPIN OR S. TO BET NUMBERS,"
180 PRINT "ENTER THE DESIRED NUMBER FOLLOWED BY YOUR BET."
190 PRINT
200 PRINT "GOOD LUCK!"
210 PLOT 6,1,3,25,31:INPUT "HIT RETURN TO CONTINUE ";I$
220 CLEAR 200
230 DIM C(38),Y(20),B(20),N(10),W(20)
240 C$= "GGRBRBRBRBRBBRBRBRBRRBRBRBRRBBBRBRBRBR"
250 FOR I= 1TO 38
260 IF MID$ (C$,I,1)= "G"THEN C(I)= 17
270 IF MID$ (C$,I,1)= "B"THEN C(I)= 3
280 IF MID$ (C$,I,1)= "R"THEN C(I)= 11
290 NEXT I
300 PLOT 6,34,12,15,27,4:PRINT "LOAD TABLE.DIS":PLOT 27,27
310 FOR I= 1TO 19:READ Y(I):NEXT I
320 REM
** PLACE BETS **
330 FOR I= 1TO 4:C= 48:GOSUB 920:IF S$= "S"THEN I= 4
340 NEXT I:IF S$= "S"THEN 520
350 FOR I= 5TO 10:C= 24:GOSUB 920:IF S$= "S"THEN I= 10
360 NEXT I:IF S$= "S"THEN 520
370 FOR I= 11TO 19:C= 60:PLOT 3,0,Y(I),6,65:PRINT "*";:PLOT 26
380 PLOT 6,C:INPUT "";B$
390 IF B$= "END"THEN LOAD "MENU":RUN
400 IF LEFT$ (B$,1)= "S"THEN I= 19:GOTO 520
410 E= I:B= INT (VAL (B$))
420 IF B$= "00"THEN B= - 1
430 IF B< - 1OR B> 36THEN B= - 99
440 N(I- 10)= B
450 PLOT 3,0,Y(I),6,C
460 C$= STR$ (B):IF B= - 99THEN C$= " "
470 IF B= - 1THEN C$= " 00"
480 C$= C$+ " ":PRINT MID$ (C$,2,7)
490 IF B< > - 99THEN GOSUB 920
500 IF S$= "S"THEN I= 19
510 NEXT I
520 REM
** SPIN THE WHEEL **
530 BK$= "N":GOSUB 1040
540 FOR I= 1TO 29:V= INT (RND (1)* 38+ 1)- 2
550 V$= STR$ (V):IF V> - 1AND V< 10THEN V$= " "+ V$
560 IF V= - 1THEN V$= " 00"
570 V$= V$+ " "
580 PLOT 3,31,0,14,6,C(V+ 2):PRINT V$
590 NEXT I
600 PLOT 15:BK$= "Y":GOSUB 1040
610 REM
** COLLECT BETS **
620 IF V< 1THEN GOTO 700
630 IF V/ 2< > INT (V/ 2)THEN W(1)= W(1)+ 2* B(1)
640 IF V/ 2= INT (V/ 2)THEN W(2)= W(2)+ 2* B(2)
650 IF C(V+ 2)= 11THEN W(3)= W(3)+ 2* B(3)
660 IF C(V+ 2)= 3THEN W(4)= W(4)+ 2* B(4)
670 IF (V+ 2)/ 3= INT ((V+ 2)/ 3)THEN W(5)= W(5)+ 3* B(5)
680 IF (V+ 1)/ 3= INT ((V+ 1)/ 3)THEN W(6)= W(6)+ 3* B(6)
690 IF V/ 3= INT (V/ 3)THEN W(7)= W(7)+ 3* B(7)
700 IF V< = 12THEN W(8)= W(8)+ 3* B(8)
710 IF V> 12AND V< 25THEN W(9)= W(9)+ 3* B(9)
720 IF V> 24THEN W(10)= W(10)+ 3* B(10)
730 FOR I= 11TO E
740 IF V= N(I- 10)THEN W(11)= W(11)+ B(I)* 37
750 NEXT I
760 REM
** PRINT RESULTS **
770 FOR I= 1TO 19:J= I:IF I> 11THEN J= 11
780 W(J)= W(J)- B(I):NEXT I
790 TW= 0
800 FOR I= 1TO 11:Y= Y(I):IF I= 11THEN Y= Y(I)- 1
810 PLOT 6,34,3,56,Y:PRINT W(I)
820 TW= TW+ W(I):NEXT I
830 PLOT 6,44,3,51,26,14:PRINT " "
840 PLOT 3,51,26:PRINT TW:PLOT 15
850 REM
** INITILAZE VARIABLES **
860 FOR I= 1TO 2000:NEXT I
870 FOR I= 1TO 19:B(I)= 0
880 C= 48:IF I> 4THEN C= 24
890 X= 7:L= 6:IF I> 10THEN X= 0:L= 13:C= 60
900 PLOT 6,C,3,X,Y(I):PRINT SPC( L);"":NEXT I
910 S$= "N":GOTO 320
920 REM
** ENTER BET **
930 PLOT 3,7,Y(I),6,65:PRINT "*";:PLOT 26
940 PLOT 6,C:INPUT "";B$
950 IF B$= "END"THEN LOAD "MENU":RUN
960 IF LEFT$ (B$,1)= "S"THEN S$= "S":RETURN
970 B= INT (VAL (B$))
980 IF B< 0THEN B= 0
990 IF B> 500THEN B= 500
1000 B(I)= B:PLOT 3,7,Y(I),6,C
1010 C$= STR$ (B)+ " "
1020 IF B= 0THEN C$= " "
1030 PRINT MID$ (C$,2,6):RETURN
1040 REM
** DISPLAY A NUMBER **
1050 Y= INT ((V- 1)/ 3):X= V+ 3- 3* Y:X= 5* X+ 6:Y= Y* 2+ 5
1060 IF V= - 1THEN X= X- 3
1070 IF V= 0THEN X= X- 2
1080 C= C(V+ 2):C$= " ":IF BK$= "Y"THEN C= C+ 64:C$= "*"
1090 PLOT 3,X,Y,6,C
1100 IF V< 10AND V< > - 1THEN PRINT " ";
1110 V$= STR$ (V):IF V= - 1THEN V$= " 00"
1120 PRINT V$;" ";
1130 PLOT 6,C,3,X,Y:PRINT C$:PLOT 3,X+ 3,Y:PRINT C$
1140 RETURN
1150 DATA 7,8,9,10,13,14,15,16,17,18
1160 DATA 22,23,24,25,26,27,28,29,30