Compucolor.org – Virtual Media

Listing of file='FILVEC.MAC;02' on disk='vmedia/asm_utility_3-sector.ccvf'

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;	FILVEC - SET UP FILE I/O JUMP VECTORS
;
	TITLE FILVEC
;
;	VALUES ON ENTRY:
;	   IRRELEVANT
;
;	RETURNS:
;	   NOTHING
;
;	DESTROYS:
;	   ALL REGISTERS
;
;	NOTE: THIS ROUTINE MUST BE CALLED BEFORE ANY FILE I/O
;	IS PERFORMED.
;
;	THE FOLLOWING FCS ROUTINES ARE INCLUDED:
;
	PUBLIC	EMESS,PFSPC,RESET,OPEN
	PUBLIC	RWSEQI,INSEQO,CLSEQO
	PUBLIC	PTBYT,GTBYT
	PUBLIC	ADHLA

	ENTRY FILVEC

FILVEC:	DI			;SET ROM ADDRESSES
	LDA	1		;VERSION 8/79?
	CPI	0BAH
	JZ	FIL20		;YES
	LXI	H,NEWTAB
	LXI	D,OLDTAB
	LXI	B,LENTAB
FIL10:	LDAX	D		; OVERLAY THE TABLE
	MOV	M,A
	INX	H
	INX	D
	DCX	B
	MOV	A,B
	ORA	C
	JNZ	FIL10
FIL20:	EI
	RET

;
; ROM JUMP TABLES
;

OLDTAB:
	JMP	262DH	;EMESS
	JMP	3077H	;PFSPC
	JMP	26A5H	;RESET
	JMP	2DABH	;OPEN
	JMP	30C6H	;RWSEQI
	JMP	30E7H	;INSEQO
	JMP	3136H	;CLSEQO
	JMP	322CH	;GTBYT
	JMP	324AH	;PTBYT
	JMP	3518H	;ADHLA

LENTAB	EQU	$-OLDTAB

NEWTAB:

EMESS:	JMP	0AD6H
PFSPC:	JMP	14ADH
RESET:	JMP	0B48H
OPEN:	JMP	11E1H
RWSEQI:	JMP	14FCH
INSEQO:	JMP	151DH
CLSEQO:	JMP	156CH
GTBYT:	JMP	1662H
PTBYT:	JMP	1680H
ADHLA:	JMP	194EH

	END